$!
$!	MAKE_$.COM -    18-Oct-1999 by David J. Dachtera
$!
$!	Provide dummy .EXE and .COM files to protect against
$!	accidentally typing an asterisk ("*") or it's 
$!	equivalent at the DCL prompt with DCL$PATH DEFINEd.
$!
$!	If necessary, you can provide ACLs for these two files
$!	to facilitate any procedures you have which may change
$!	your process's UIC.
$!
$!----------------------------------------------------------------------
$!
$ IF F$TRNLNM( "DCL$PATH",,,,, "MAX_INDEX" ) .EQS. "" THEN -
$ EXIT
$!
$ CREATE $.MAR
	.title $
	.subtitle       "Null" program to protect DCL$PATH
	.ident          /$ V1.0/
	.disable        debug
	.disable        traceback
;
	.entry  NULL,^M<>
	ret
	.end    NULL
$ EOD
$ IF	F$GETSYI( "HW_NAME" ) .EQS. "Alpha"
$ THEN
$	ASM := MACRO/MIGRATE/OBJECT
$ ELSE
$	ASM := MACRO/OBJECT
$ ENDIF
$ ASM $
$ LINK $
$ COPY $.EXE DCL$PATH
$ SET FILE/PROT=(S:RE,O:RE,G,W) DCL$PATH:$.EXE
$ DELETE/NOLOG/NOCONFIRM $.MAR;,$.OBJ;,$.EXE;
$ CREATE DCL$PATH:$.COM
$DECK
$!
$! *** DO NOT DELETE THIS .COM FILE ***
$ EXIT
$EOD
$ SET FILE/PROT=(S:R,O:R,G,W) DCL$PATH:$.COM
$ EXIT